Modules

5.83 Impostare da VBA l'icona ed il titolo dell'applicazione e l'icona delle maschere e report
  Roberto Arisi, Roberto

Per impostare da VBA l'icona ed il titolo dell'applicazione occorre memorizzare in un modulo standard del database le seguenti funzioni:
Public Function IconaApp(Icona As String, Titolo As String)
'Scritto da Arisi Roberto
'Icona è una variabile stringa che contiene il nome di un file icona contenuto nella stessa cartelle che contiene il database
'Titolo è una variabile stringa che contiene il titolo da assegnare all'applicazione

    Dim intX As Integer
    Dim strPAthDB As String
    Const DB_Text As Long = 10
    intX = AddAppProperty("AppTitle", DB_Text, Titolo)
    strPAthDB = Left(CurrentDb.name, Len(CurrentDb.name) - Len(Dir(CurrentDb.name)))
    intX = AddAppProperty("AppIcon", DB_Text, strPAthDB & Icona)
    'CurrentDb.Properties("UseAppIconForFrmRpt") = 1 'abilitare solo per versioni successive ad Access 2000 per impostare l'icona anche per tutte le maschere e tutti i report
    Application.RefreshTitleBar
End Function

Public Function AddAppProperty(strName As String, varType As Variant, varValue As Variant) As Integer
    Dim dbs As Object, prp As Variant
    Const conPropNotFoundError = 3270
    Set dbs = CurrentDb
    On Error GoTo AddProp_Err
    dbs.Properties(strName) = varValue
    AddAppProperty = True
AddProp_Bye:
    Exit Function
AddProp_Err:
    If err = conPropNotFoundError Then
        Set prp = dbs.CreateProperty(strName, varType, varValue)
        dbs.Properties.Append prp
        Resume
    Else
        AddAppProperty = False
        Resume AddProp_Bye
    End If
End Function
Se si usa una versione di Access successiva ad Access 2000 e si vuole impostare la stessa icona dell'applicazione anche per tutte le maschere e tutti i report, attivare la riga di codice:
CurrentDb.Properties("UseAppIconForFrmRpt") = 1
che nella funzione IconaApp di cui sopra è inserita solo come commento.

Per effetuare le impostazioni occorre richiamare la funzione IconaApp() (ad esempio dalla macro Autoexec) nel modo seguente:
Call IconaApp("img2.ico", "Mia applicazione")
dove img2.ico è il nome di un file icona contenuto nella stessa cartella che contiene il database, mentre Mia applicazione è il titolo che si vuole assegnare all'applicazione.

Se pensate di avere del materiale freeware interessante e volete pubblicarlo, allora leggete qui.