Public Function AccodaTabella(TabDa As String, TabA As String) As String
'Autore: Lorenzo Coronati
'Ritorna una stringa sql per accodare i record della TabDa in TabA
'impostando a null eventuali campi presenti solo in TabA
   Dim d As DAO.Database
   Set d = CurrentDb
   Dim t As DAO.TableDef, t1 As DAO.TableDef
   Set t = d.TableDefs(TabDa)
   Set t1 = d.TableDefs(TabA)
   Dim s As String
   s = "INSERT INTO " & TabA & " (##) SELECT §§ FROM " & TabDa & ";"
   Dim f As DAO.Field
   For Each f In t1.Fields
      s = SostituisciStringa(s, f.Name & ", ##", "##")
      If EsisteCampo(t, f.Name) Then
         s = SostituisciStringa(s, TabDa & "." & f.Name & ", §§", "§§")
      Else
         s = SostituisciStringa(s, "null, §§", "§§")
      End If
   Next f
   s = EliminaStringa(s, ", ##")
   s = EliminaStringa(s, ", §§")
   AccodaTabella = s
End Function

Public Function EsisteCampo(t As TableDef, c As String) As Boolean
   On Error GoTo annulla
   Debug.Print t.Fields(c).Name
   EsisteCampo = True
   Exit Function
annulla:
   EsisteCampo = False
End Function

Public Function SostituisciStringa(campo As String, commento As String, car As String) As String
   Dim i As Integer
   i = InStr(1, campo, car) - 1
   SostituisciStringa = Left(campo, i)
   SostituisciStringa = SostituisciStringa & commento & Right(campo, Len(campo) - i - Len(car))
End Function

Public Function EliminaStringa(s As String, car As String) As String
   EliminaStringa = Left(s, InStr(1, s, car) - 1) & Right(s, Len(s) - InStr(1, s, car) - Len(car) + 1)
End Function